best preg_replace functions?

[pluggz]

i need a little snippet of code to parse some links..

i need to convert links in ALL forms (including..):

http://www.yahoo.com
http://www.yahoo.com/
http://yahoo.com
http://yahoo.com/
http://www.yahoo.com/dir
http://www.yahoo.com/dir/
www.yahoo.com
www.yahoo.com/
www.yahoo.com/dir
www.yahoo.com/dir/

for [url]http://,[/url] [url]https://,[/url] [url]gopher://,[/url] [url]ftp://,[/url] irc://, [url]news://[/url] and replace it with

<a href="([url]http://[/url])[/SITE]">[link]</a> for [url]http://,[/url] [url]https://[/url]
<a ...>[gopher]</a> for [url]gopher://[/url]
<a ...>[ftp]</a> for [url]ftp://[/url]
<a ...>[news]</a> for [url]news://[/url]
<a ...>[irc]</a> for irc://

as well as mailto:[e-mail] and [e-mail] to <a ...>[mail]</a>

is there any good code to do all this?

[Weedpacket]

That's a lot for one regexp to do. You're looking at more elaborate parsing there.

This isn't a regexp, but a grammar. Pretty straightforward: "?" | ":" | "@" | "&" would be written in a regexp as [?:@&], for example, and ";" fieldname "=" fieldvalue means "a semicolon followed by a fieldname (defined elsewhere) followed by an equals sign followed by a fieldvalue (defined elsewhere).

It covers http, https, ftp, news, nntp, telnet, gopher, wais, mailto, file, prospero and generic urls. It only handles complete (full) URLs, not just "www.example.com", and does not check that protocl-specific things like email addresses or ftp paths are valid.

In other words - you're asking a fair bit 🙂

; The generic form of a URL is:

genericurl     = scheme ":" schemepart

; Specific predefined schemes are defined here; new schemes
; may be registered with IANA

url            = httpurl | httpsurl | ftpurl | newsurl |
                 nntpurl | telneturl | gopherurl |
                 waisurl | mailtourl | fileurl |
                 prosperourl | otherurl


; new schemes follow the general syntax
otherurl       = genericurl

; the scheme is in lower case; interpreters should use case-ignore
scheme         = ( lowalpha | digit | "+" | "-" | "." )+
schemepart     = *xchar | ip-schemepart

; URL schemeparts for ip based protocols:

ip-schemepart  = "//" login ( "/" urlpath )?

login          = ( user ( ":" password )? "@" )? hostport
hostport       = host ( ":" port )?
host           = hostname | hostnumber
hostname       = ( domainlabel "." )* toplabel
domainlabel    = alphadigit | alphadigit ( alphadigit | "-" )* alphadigit
toplabel       = alpha | alpha ( alphadigit | "-" )* alphadigit
alphadigit     = alpha | digit
hostnumber     = digits "." digits "." digits "." digits
port           = digits
user           = ( uchar | ";" | "?" | "&" | "=" )*
password       = ( uchar | ";" | "?" | "&" | "=" )*
urlpath        = xchar*    ; depends on protocol see section 3.1

; The predefined schemes:

; FTP (see also RFC959)

ftpurl         = "ftp://" login ( "/" fpath [ ";type=" ftptype )?)?
fpath          = fsegment ( "/" fsegment )*
fsegment       = ( uchar | "?" | ":" | "@" | "&" | "=" )*
ftptype        = "A" | "I" | "D" | "a" | "i" | "d"

; FILE

fileurl        = "file://" ( host | "localhost" )? "/" fpath

; HTTP/HTTPs

httpurl        = "http://" hostport ( "/" hpath ( "?" search )?)?
httpsurl       = "https://" hostport ( "/" hpath ( "?" search )?)?
hpath          = hsegment ( "/" hsegment )*
hsegment       = ( uchar | ";" | ":" | "@" | "&" | "=" )*
search         = ( uchar | ";" | ":" | "@" | "&" | "=" )*

; GOPHER (see also RFC1436)

gopherurl      = "gopher://" hostport ( / ( gtype ( selector
                 ( "%09" search ( "%09" gopher+_string )?)?)?)?)?
gtype          = xchar
selector       = xchar*
gopher+_string = xchar*

; MAILTO (see also RFC822)

mailtourl      = "mailto:" encoded822addr
encoded822addr = xchar+               ; further defined in RFC822

; NEWS (see also RFC1036)

newsurl        = "news:" grouppart
grouppart      = "*" | group | article
group          = alpha ( alpha | digit | "-" | "." | "+" | "_" )*
article        = ( uchar | ";" | "/" | "?" | ":" | "&" | "=" )+ "@" host

; NNTP (see also RFC977)

nntpurl        = "nntp://" hostport "/" group ( "/" digits )?

; TELNET

telneturl      = "telnet://" login ( "/" )?

; WAIS (see also RFC1625)

waisurl        = waisdatabase | waisindex | waisdoc
waisdatabase   = "wais://" hostport "/" database
waisindex      = "wais://" hostport "/" database "?" search
waisdoc        = "wais://" hostport "/" database "/" wtype "/" wpath
database       = uchar*
wtype          = uchar*
wpath          = uchar*

; PROSPERO

prosperourl    = "prospero://" hostport "/" ppath ( fieldspec )*
ppath          = psegment ( "/" psegment )*
psegment       = ( uchar | "?" | ":" | "@" | "&" | "=" )*
fieldspec      = ";" fieldname "=" fieldvalue
fieldname      = ( uchar | "?" | ":" | "@" | "&" )*
fieldvalue     = ( uchar | "?" | ":" | "@" | "&" )*

; Miscellaneous definitions

lowalpha       = "a" | "b" | "c" | "d" | "e" | "f" | "g" | "h" |
                 "i" | "j" | "k" | "l" | "m" | "n" | "o" | "p" |
                 "q" | "r" | "s" | "t" | "u" | "v" | "w" | "x" |
                 "y" | "z"
hialpha        = "A" | "B" | "C" | "D" | "E" | "F" | "G" | "H" | "I" |
                 "J" | "K" | "L" | "M" | "N" | "O" | "P" | "Q" | "R" |
                 "S" | "T" | "U" | "V" | "W" | "X" | "Y" | "Z"
alpha          = lowalpha | hialpha
digit          = "0" | "1" | "2" | "3" | "4" | "5" | "6" | "7" |
                 "8" | "9"
safe           = "$" | "-" | "_" | "." | "+"
extra          = "!" | "*" | "'" | "(" | ")" | ","
national       = "{" | "}" | "|" | "\" | "^" | "~" | "[" | "]" | "`"
punctuation    = "<" | ">" | "#" | "%" | <">

reserved       = ";" | "/" | "?" | ":" | "@" | "&" | "="
hex            = digit | "A" | "B" | "C" | "D" | "E" | "F" |
                 "a" | "b" | "c" | "d" | "e" | "f"
escape         = "%" hex hex


unreserved     = alpha | digit | safe | extra
uchar          = unreserved | escape
xchar          = unreserved | reserved | escape
digits         = digit+

[pluggz]

thanks, but i need a regex (or 2 or 3) that just <a href="URL">[web]</a> a link.. i need several regex to match URL's. i need to prevent my users from posting a link that will mess up a small iframe.

[yelvington]

Here's a bit of code from Tobias Rathschiller of phpwizard.net fame. It transforms URLs of the form
protocol://string and mailbox@host, but it is NOT bulletproof, for the reasons weedpacket identified -- the problem is much harder than it looks. This function also will not detect urls of the form www.string.string.

 <?
function make_clickable($text)
{
    $ret = eregi_replace("([[:alnum:]]+)://([^[:space:]]*)([[:alnum:]#?/&=])", 
"<a href=\"\\1://\\2\\3\" target=\"_blank\" 
target=\"_new\">\\1://\\2\\3</a>", $text);
    $ret = eregi_replace("(([a-z0-9_]|\\-|\\.)+@([^[:space:]]*)([[:alnum:]-]))",
 "<a href=\"mailto:\\1\" target=\"_new\">\\1</a>", $ret);
        return($ret);
}

print(make_clickable("This is an email address: [email][e-mail][/email]"));
?>

[pluggz]

hmm.. i can't even get that code to work, yelvington.. it just shows up as:

This is an email address:

with the box () being a link to mailto:

This is an email address: <a href="mailto:" target="_new"></a>

[pluggz]

found the bug.. it has to be \1 instead of \1

[pluggz]

alright.. i'm using this code:

function make_clickable($text) {
$ret = eregi_replace("([[:alnum:]]+)://([^{[:space:]])([[:alnum:]#?/&=])",} "<a href=\"\1://\2\3\" target=\"_blank\">[\1]</a>", $text);
$ret = str_replace("[http]","[www]",$ret);
$ret = str_replace("[https]","[www]",$ret);
$ret = eregi_replace("(([a-z0-9_]|-|.)+@([^[:space:]])([[:alnum:]-]))", "<a href=\"mailto:\1\" target=\"_new\">\1</a>", $ret);
return($ret);
}

everything works correctly but the [url]ftp://[/url]

print(make_clickable("ftp://user:[e-mail]")) returns:

<a href="ftp://user:<a href="mailto:[e-mail]" target="_new">[e-mail]</a>" target="_blank">[ftp]</a>

where i want it to return:

<a href="ftp://user:[e-mail]" target="_blank">[ftp]</a>

it is treating it as an email address, also, port support would be great (i.e. [url]ftp://user:[e-mail]:2125[/url])

[pluggz]

solved it..

function make_clickable($text) {
  $ret = eregi_replace("([[:alnum:]]+)://([^[:space:]]*)([[:alnum:]#?/&=])", "<a href=\"\\1://\\2\\3\" target=\"_blank\">[\\1]</a>", $text);
  $ret = str_replace("[http]","[www]",$ret);
  $ret = str_replace("[https]","[www]",$ret);
  if (!strstr($ret,"ftp://")) {
    $ret = eregi_replace("(([a-z0-9_]|\-|\.)+@([^[:space:]]*)([[:alnum:]-]))", "<a href=\"mailto:\\1\" target=\"_new\">\\1</a>", $ret);
  }
  return($ret);
}

print(make_clickable("ftp://user:site@192.168.0.1:3054"));

it works 🙂 thanks guys!